plugins {
    id "com.android.application"
    id "org.jetbrains.kotlin.android"
}

android {
    namespace = "pro.relaytv"
    compileSdk = 35

    defaultConfig {
        applicationId = "pro.relaytv"
        minSdk = 26
        targetSdk = 35
        versionCode = 6
        versionName = "1.3.0"
    }

    // Release signing is configured via gradle.properties (see todo.md /
    // docs/RELEASE_CHECKLIST.md); without those properties the release
    // build stays unsigned so CI and local debug workflows keep working.
    signingConfigs {
        release {
            if (project.hasProperty("MYAPP_RELEASE_STORE_FILE")) {
                storeFile = file(MYAPP_RELEASE_STORE_FILE)
                storePassword = MYAPP_RELEASE_STORE_PASSWORD
                keyAlias = MYAPP_RELEASE_KEY_ALIAS
                keyPassword = MYAPP_RELEASE_KEY_PASSWORD
            }
        }
    }

    buildTypes {
        release {
            minifyEnabled = true
            shrinkResources = true
            proguardFiles(
                getDefaultProguardFile("proguard-android-optimize.txt"),
                "proguard-rules.pro"
            )
            if (project.hasProperty("MYAPP_RELEASE_STORE_FILE")) {
                signingConfig = signingConfigs.release
            }
        }
        debug {
            minifyEnabled = false
        }
    }

    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_17
        targetCompatibility = JavaVersion.VERSION_17
    }
    kotlinOptions {
        jvmTarget = "17"
    }
}

dependencies {
    implementation "androidx.core:core-ktx:1.13.1"
    implementation "androidx.appcompat:appcompat:1.7.0"
    implementation "androidx.activity:activity-ktx:1.9.2"
    implementation "com.google.android.material:material:1.12.0"

    implementation "com.squareup.okhttp3:okhttp:4.12.0"
    implementation "androidx.work:work-runtime-ktx:2.9.1"
    implementation "androidx.media3:media3-session:1.7.1"
}